* Wealth index calculation. Claudia Marchena, 04/25/2019. Papua New Guinea DHS 2016-18.
cd 'C:\PG71\wealth'.
include file='wealth_assets.sps'.
missing values QH120 (99.9).
execute.
set tvars=both.

* Macro definitions to perform some recoding automatically.
* Note: Do not use an asterisk in front of a macro name to try to comment it out - it will run any way because of the way the macros are expanded.
* Delete the line instead or change the spelling of the macro in the comment.
* Do not use the names of macros in comments - they will also be expanded too, and likely will fail.

*{Create binary variables based on condition and give label }.
define dichotomize( !positional !enclose('(',')') / !positional !tokens(1) / !positional !tokens(1) )
compute !2=0.
if (!1) !2=1.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*(Separate shared toilets from non-shared toilets).
define shared_fac( !positional !tokens(1) / !positional !tokens(1) / !positional !tokens(1) ).
compute !2 = 0.
do if (QH110=1).
+ if (!1=1) !2 = 1.
+ compute !1 = 0.
end if.
variable labels !2 !3.
value labels !2 0 'No' 1 'Yes'.
formats !2 (f1.0).
!enddefine.

*{Reset missing values to 'does not have', change 2 code to 0}.
define no2zero( !positional !tokens(1) )
if (missing(!1) | !1<>1) !1=0.
value labels !1 0 'No' 1 'Yes'.
!enddefine.

*{Construct Variables}.

* Source of drinking water.
dichotomize (QH101=11) QH101_11 "Source of drinking water: Piped - into dwelling".
dichotomize (QH101=12) QH101_12 "Source of drinking water: Piped - to yard/plot".
dichotomize (QH101=13) QH101_13 "Source of drinking water: Piped - to neighbor".
dichotomize (QH101=14) QH101_14 "Source of drinking water: Piped - public tap / standpipe".
dichotomize (QH101=21) QH101_21 "Source of drinking water: Tube well or borehole".
dichotomize (QH101=31) QH101_31 "Source of drinking water: Dug well - protected".
dichotomize (QH101=32) QH101_32 "Source of drinking water: Dug well - unprotected".
dichotomize (QH101=41) QH101_41 "Source of drinking water: Spring - protected".
dichotomize (QH101=42) QH101_42 "Source of drinking water: Spring - unprotected".
dichotomize (QH101=51) QH101_51 "Source of drinking water: Rainwater".
dichotomize (QH101=61) QH101_61 "Source of drinking water: Tanker truck".
dichotomize (QH101=71) QH101_71 "Source of drinking water: Cart with small tank".
dichotomize (QH101=81) QH101_81 "Source of drinking water: Surface water (river/dam/lake/pond/stream/canal/irrigation channel)".
dichotomize (QH101=91) QH101_91 "Source of drinking water: Bottled water".
dichotomize (QH101=96) QH101_96 "Source of drinking water: Other".


* Type of toilet facility.
dichotomize (QH109=11) QH109_11 "Type of toilet facility: Flush - to piped sewer system".
dichotomize (QH109=12) QH109_12 "Type of toilet facility: Flush - to septic tank".
dichotomize (QH109=13) QH109_13 "Type of toilet facility: Flush - to pit latrine".
dichotomize (QH109=14 or QH109=15) QH109_14 "Type of toilet facility: Flush - to somewhere else".
*ichotomize (QH109=15) QH109_15 "Type of toilet facility: Flush - don't know where".
dichotomize (QH109=21) QH109_21 "Type of toilet facility: Pit latrine - ventilated improved pit (VIP)".
dichotomize (QH109=22) QH109_22 "Type of toilet facility: Pit latrine - with slab".
dichotomize (QH109=23) QH109_23 "Type of toilet facility: Pit latrine - without slab/open pit".
dichotomize (QH109=31) QH109_31 "Type of toilet facility: Composting toilet".
dichotomize (QH109=41) QH109_41 "Type of toilet facility: Bucket toilet".
dichotomize (QH109=51) QH109_51 "Type of toilet facility: Hanging toilet/hanging latrine".
dichotomize (QH109=61) QH109_61 "Type of toilet facility: No facility/bush/field".
dichotomize (QH109=96) QH109_96 "Type of toilet facility: Other".

shared_fac QH109_11 QH109_11_sh "Type of toilet facility: Flush - to piped sewer system - shared".
shared_fac QH109_12 QH109_12_sh "Type of toilet facility: Flush - to septic tank - shared".
shared_fac QH109_13 QH109_13_sh "Type of toilet facility: Flush - to pit latrine - shared".
shared_fac QH109_14 QH109_14_sh "Type of toilet facility: Flush - to somewhere else - shared".
*hared_fac QH109_15 QH109_15_sh "Type of toilet facility: Flush - don't know where - shared".
shared_fac QH109_21 QH109_21_sh "Type of toilet facility: Pit latrine - ventilated improved pit (VIP) - shared".
shared_fac QH109_22 QH109_22_sh "Type of toilet facility: Pit latrine - with slab - shared".
shared_fac QH109_23 QH109_23_sh "Type of toilet facility: Pit latrine - without slab/open pit - shared".
shared_fac QH109_31 QH109_31_sh "Type of toilet facility: Composting toilet - shared".
shared_fac QH109_41 QH109_41_sh "Type of toilet facility: Bucket toilet - shared".
shared_fac QH109_51 QH109_51_sh "Type of toilet facility: Hanging toilet/hanging latrine - shared".
shared_fac QH109_96 QH109_96_sh "Type of toilet facility: Other - shared".


* Main source of lighting.
dichotomize (QH112A=1) QH112A_1 "Main source of lighting: Electricity".
dichotomize (QH112A=2) QH112A_2 "Main source of lighting: Pressure lamp (Coleman)".
dichotomize (QH112A=3) QH112A_3 "Main source of lighting: Kerosene".
dichotomize (QH112A=4) QH112A_4 "Main source of lighting: Solar lighting".
dichotomize (QH112A=5) QH112A_5 "Main source of lighting: Candles".
dichotomize (QH112A=6) QH112A_6 "Main source of lighting: Open fire".
dichotomize (QH112A=7) QH112A_7 "Main source of lighting: Lantern (battery operated)".
dichotomize (QH112A=96) QH112A_96 "Main source of lighting: Other".


* Type of cooking fuel.
recode QH113 (6,11 = 96).
dichotomize (QH113=1) QH113_1 "Type of cooking fuel: Electricity".
dichotomize (QH113=2) QH113_2 "Type of cooking fuel: Gas (LPG)".
dichotomize (QH113=3) QH113_3 "Type of cooking fuel: Kerosene".
dichotomize (QH113=4) QH113_4 "Type of cooking fuel: Charcoal".
dichotomize (QH113=5) QH113_5 "Type of cooking fuel: Wood".
dichotomize (QH113=95) QH113_95 "Type of cooking fuel: No food cooked in household".
dichotomize (QH113=96) QH113_96 "Type of cooking fuel: Other".


* Pigs.
if (missing(QH118A) | QH117 <> 1) QH118A=0.
missing values QH118A (99).
compute QH118A_1 = (QH118A >= 1 & QH118A <= 4).
compute QH118A_2 = (QH118A >= 5 & QH118A <= 9).
compute QH118A_3 = (QH118A >= 10 & QH118A <98).
variable labels QH118A_1 'Pigs: 1-4' /QH118A_2 'Pigs: 5-9' /QH118A_3 'Pigs: 10+'.


* Chickens.
if (missing(QH118B) | QH117 <> 1) QH118B=0.
missing values QH118B (99).
compute QH118B_1 = (QH118B >= 1 & QH118B <= 9).
compute QH118B_2 = (QH118B >= 10 & QH118B <= 29).
compute QH118B_3 = (QH118B >= 30 & QH118B < 98).
variable labels QH118B_1 'Chickens: 1-9' /QH118B_2 'Chickens: 10-29' /QH118B_3 'Chickens: 30+'.


* Sheep.
if (missing(QH118C) | QH117 <> 1) QH118C=0.
missing values QH118C (99).
compute QH118C_1 = (QH118C >= 1 & QH118C <= 4).
compute QH118C_2 = (QH118C >= 5 & QH118C <= 9).
compute QH118C_3 = (QH118C >= 10 & QH118C <98).
variable labels QH118C_1 'Sheep: 1-4' /QH118C_2 'Sheep: 5-9' /QH118C_3 'Sheep: 10+'.


* Goats.
if (missing(QH118D) | QH117 <> 1) QH118D=0.
missing values QH118D (99).
compute QH118D_1 = (QH118D >= 1 & QH118D <= 4).
compute QH118D_2 = (QH118D >= 5 & QH118D <= 9).
compute QH118D_3 = (QH118D >= 10 & QH118D < 98).
variable labels QH118D_1 'Goats: 1-4' /QH118D_2 'Goats: 5-9' /QH118D_3 'Goats: 10+'.


* Cows/bulls.
if (missing(QH118E) | QH117 <> 1) QH118E=0.
missing values QH118E (99).
compute QH118E_1 = (QH118E >= 1 & QH118E <= 4).
*compute QH118E_2 = (QH118E >= 5 & QH118E <= 9).
compute QH118E_3 = (QH118E >= 5 & QH118E < 98).
variable labels QH118E_1 'Cows/bulls: 1-4' /QH118E_3 'Cows/bulls: 5+'.


* Buffalo.
if (missing(QH118F) | QH117 <> 1) QH118F=0.
missing values QH118F (99).
compute QH118F_1 = (QH118F >= 1 & QH118F <= 4).
*compute QH118F_2 = (QH118F >= 5 & QH118F <= 9).
compute QH118F_3 = (QH118F >= 5 & QH118F < 98).
variable labels QH118F_1 'Buffalo: 1-4' /QH118F_3 'Buffalo: 5+'.


* Cassowary.
if (missing(QH118G) | QH117 <> 1) QH118G=0.
missing values QH118G (99).
compute QH118G_1 = (QH118G >= 1 & QH118G <= 4).
compute QH118G_2 = (QH118G >= 5 & QH118G <= 9).
compute QH118G_3 = (QH118G >= 10 & QH118G < 98).
variable labels QH118G_1 'Cassowary: 1-4' /QH118G_2 'Cassowary: 5-9' /QH118G_3 'Cassowary: 10+'.


* Ducks.
if (missing(QH118H) | QH117 <> 1) QH118H=0.
missing values QH118H (99).
compute QH118H_1 = (QH118H >= 1 & QH118H <= 9).
compute QH118H_2 = (QH118H >= 10 & QH118H <= 29).
compute QH118H_3 = (QH118H >= 30 & QH118H < 98).
variable labels QH118H_1 'Ducks: 1-9' /QH118H_2 'Ducks: 10-29' /QH118H_3 'Ducks: 30+'.


* Other.
if (missing(QH118I) | QH117 <> 1) QH118I=0.
missing values QH118I (99).
compute QH118I_1 = (QH118I >= 1 & QH118I <= 4).
compute QH118I_2 = (QH118I >= 5 & QH118I <= 9).
compute QH118I_3 = (QH118I >= 10 & QH118I < 98).
variable labels QH118I_1 'Other: 1-4' /QH118I_2 'Other: 5-9' /QH118I_3 'Other: 10+'.


* Hectares for agricultural land.
compute landarea = QH120.
if (missing(QH120) | QH120 >= 99.8) landarea = 99.9.
if (missing(QH119) | QH119 <> 1) landarea=0.
missing values landarea (99.9).

* Electricity.
no2zero QH121A.
* Watch.
no2zero QH121B.
* Radio.
no2zero QH121C.
* Television.
no2zero QH121D.
* Mobile telephone.
no2zero QH121E.
* Non-mobile telephone.
no2zero QH121F.
* Computer/laptop.
no2zero QH121G.
* Refrigerator.
no2zero QH121H.
* Bicycle.
no2zero QH122A.
* Mobile telephone.
no2zero QH122B.
* Motorcycle or scooter.
no2zero QH122C.
* Animal-drawn cart.
no2zero QH122D.
* Car or Truck.
no2zero QH122E.
* Boat with a motor.
no2zero QH122F.
* Bank account.
no2zero QH123.

* Main floor material.
dichotomize (QH142=11) QH142_11 "Main floor material: Earth/sand".
dichotomize (QH142=21) QH142_21 "Main floor material: Wood planks".
dichotomize (QH142=22) QH142_22 "Main floor material: Palm/bamboo".
dichotomize (QH142=31) QH142_31 "Main floor material: Polished wood".
dichotomize (QH142=32) QH142_32 "Main floor material: Vinyl or asphalt strips".
dichotomize (QH142=33) QH142_33 "Main floor material: Ceramic tiles".
dichotomize (QH142=34) QH142_34 "Main floor material: Cement".
dichotomize (QH142=35) QH142_35 "Main floor material: Carpet".
dichotomize (QH142=36) QH142_36 "Main floor material: Unpolished floor".
dichotomize (QH142=96) QH142_96 "Main floor material: Other".


* Main roof material.
recode QH143 (21,36 = 96).
dichotomize (QH143=11) QH143_11 "Main roof material: No roof".
dichotomize (QH143=12) QH143_12 "Main roof material: Thatch/palm leaf".
*ichotomize (QH143=13) QH143_13 "Main roof material: Sod".
*ichotomize (QH143=21) QH143_21 "Main roof material: Rustic mat".
dichotomize (QH143=22) QH143_22 "Main roof material: Palm/bamboo".
dichotomize (QH143=23) QH143_23 "Main roof material: Wood planks".
*ichotomize (QH143=24) QH143_24 "Main roof material: Cardboard".
dichotomize (QH143=31) QH143_31 "Main roof material: Metal".
dichotomize (QH143=32) QH143_32 "Main roof material: Wood".
*ichotomize (QH143=33) QH143_33 "Main roof material: Calamine/cement fiber".
*ichotomize (QH143=34) QH143_34 "Main roof material: Ceramic tiles".
dichotomize (QH143=35) QH143_35 "Main roof material: Cement".
*ichotomize (QH143=36) QH143_36 "Main roof material: Roofing shingles".
dichotomize (QH143=96) QH143_96 "Main roof material: Other".


* Main wall material.
recode QH144 (23 = 96).
dichotomize (QH144=11) QH144_11 "Main wall material: No walls".
dichotomize (QH144=12) QH144_12 "Main wall material: Cane/palm/trunks".
*ichotomize (QH144=13) QH144_13 "Main wall material: Dirt".
dichotomize (QH144=21) QH144_21 "Main wall material: Bamboo with mud".
*ichotomize (QH144=22) QH144_22 "Main wall material: Stone with mud".
*ichotomize (QH144=23) QH144_23 "Main wall material: Uncovered adobe".
dichotomize (QH144=24) QH144_24 "Main wall material: Plywood".
dichotomize (QH144=25) QH144_25 "Main wall material: Cardboard".
dichotomize (QH144=26) QH144_26 "Main wall material: Reused wood".
dichotomize (QH144=31) QH144_31 "Main wall material: Cement".
dichotomize (QH144=32) QH144_32 "Main wall material: Stone with lime/cement".
dichotomize (QH144=33) QH144_33 "Main wall material: Bricks".
dichotomize (QH144=34) QH144_34 "Main wall material: Cement blocks".
*ichotomize (QH144=35) QH144_35 "Main wall material: Covered adobe".
dichotomize (QH144=36) QH144_36 "Main wall material: Wood planks/shingles".
dichotomize (QH144=37) QH144_37 "Main wall material: Fibro".
dichotomize (QH144=38) QH144_38 "Main wall material: Metal/Tin sheet".
dichotomize (QH144=96) QH144_96 "Main wall material: Other".


*{Members per sleeping room}.
if (hhusual=0) hhusual=hhslept.
if (QH116>0) memsleep=trunc(hhusual/QH116).
if (QH116=0) memsleep=hhusual.
if (missing(QH116) or QH116>=99 or memsleep>=98) memsleep=99.
variable labels memsleep 'Number of members per sleeping room'.
value labels memsleep 0 'Less than 1 per room'.
formats memsleep (f2.0).
missing values memsleep (99).

* Compute urban and rural variables coded (1/0) for filters later.
compute urban=(QHTYPE = 1).
compute rural=(QHTYPE = 2).
variable labels urban 'Urban' / rural 'Rural'.
value labels urban 1 'Urban' / rural 1 'Rural'.
formats urban rural (f1.0).

execute.

* Check on indicator variable creation. note should be Land.
frequencies variables=QHTYPE to land.

* Toilet facility by shared/not shared.
crosstabs /tables=QH109 by QH110.

* Land area by units - if there are separate units - need to convert them to one unit.
*crosstabs /tables=QH120N by QH120U.

frequencies variables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 DOMESTIC HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_3 QH118F_1 QH118F_3
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
.

* Turn off weights before all factor analysis.
weight off.

* Name the dataset window for the HH data for use later.
dataset name assets.

save outfile='assets.sav'.

*** Test Factor Analysis.
filter off.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_3
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_3
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /method=correlation.

*** Common Factor analysis ***.
** Removed area-specific variables **.
** Agricultural animal variables excluded
** Land area excluded
** Any others ?.

*** Common Factor Analysis.
filter off.
execute.

factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL com)
  /method=correlation.

*** Urban Factor Analysis.
filter off.
filter by urban.
execute.

*Removed: QH109_41_SH QH113_95, QH118C_2, QH118C_3 QH118D_3 QH118E_2, QH118F_1, QH118F_2, QH118G_2 QH118G_3.
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118D_1 QH118D_2
  QH118E_1 QH118E_3
  QH118G_1 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118D_1 QH118D_2
  QH118E_1 QH118E_3
  QH118G_1 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL urb)
  /method=correlation.

*** Rural Factor Analysis.
filter off.
filter by rural.
execute.

*Removed QH118E2 QH118F_2 QH118F_3.
factor /variables
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_3 QH118F_1
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /missing meansub
  /analysis
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_3 QH118F_1
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
  /print univariate initial extraction fscore
  /criteria factors(1) iterate(25)
  /extraction pc
  /rotation norotate
  /save reg(ALL rur)
  /method=correlation.

* Label the created score variables.
rename variables (com1 urb1 rur1=comscore urbscore rurscore).
variable labels comscore 'Common wealth score' /urbscore 'Urban wealth score' /rurscore 'Rural wealth score'.

* Add a variable used for linking later.
filter off.
string rowtype_ (A8).
compute rowtype_ = 'EST'.

* Calculate regressions.
** Area=urban.
filter off.
filter by urban.
execute.

* Declare a dataset to be written to in the regression.
dataset declare urbancorv.
* Run regression of comscore with urbscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter urbscore
  /outfile=corv(urbancorv).

* Activate file of output from regression.
dataset activate urbancorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=urbconst urbscore=urbcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = urbancorv
  /by ROWTYPE_.
execute.

* Calculate regressions.
** Area=rural.
filter off.
filter by rural.
execute.

* Declare a dataset to be written to in the regression.
dataset declare ruralcorv.
* Run regression of comscore with rurscore.
regression
  /missing listwise
  /statistics coeff outs R anova
  /criteria=pin(.05) pout(.10)
  /noorigin
  /dependent comscore
  /method=enter rurscore
  /outfile=corv(ruralcorv).

* Activate file of output from regression.
dataset activate ruralcorv.
* Drop all rows of output except the coefficients.
select if (rowtype_ = 'EST').
execute.
* Delete unnecessary variables before merging.
delete variables DEPVAR_ VARNAME_.
* Rename variables containing the constant and the coefficient.
rename variables CONST_=rurconst rurscore=rurcoeff.

* Re-activate the main household data.
dataset activate assets.
* merge the coefficients.
match files /file = *
  /table = ruralcorv
  /by ROWTYPE_.
execute.

dataset close urbancorv.
dataset close ruralcorv.
dataset activate assets.
filter off.

*** Calculate combined wealth score from Urban and Rural Scores.
* Use coefficients from urban and rural regressions above.
compute combscor=0.
print formats combscor (f11.5).
write formats combscor (f11.5).
** Urban.
if (urban = 1) combscor=urbconst+urbcoeff*urbscore.
** Rural.
if (rural = 1) combscor=rurconst+rurcoeff*rurscore.
variable labels combscor 'Combined national wealth score'.
execute.

compute hhwt = QHWEIGHT/1000000.
variable labels hhwt 'HH weights'.
formats hhwt (f12.6).
weight by hhwt.

filter off.
execute.

frequencies variables=combscor comscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by urban.
execute.

frequencies variables=combscor urbscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
filter by rural.
execute.

frequencies variables=combscor rurscore
  /format=notable
  /ntiles=5
  /statistics=minimum maximum stddev mean
  /histogram normal
  /order=analysis.

filter off.
execute.

*Calculate quintiles and scores for data file.
compute hhmemwt=QHWEIGHT*hhusual/1000000.
variable labels hhmemwt 'HH members weighting for index'.
formats hhmemwt (f12.6).
weight by hhmemwt.

filter off.
filter by urban.
execute.

rank variables=urbscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
filter by rural.
execute.

rank variables=rurscore (A) /rank /ntiles (5) /print=yes /ties=mean.

filter off.
execute.

rank variables=combscor (A) /rank /ntiles (5) /print=yes /ties=mean.

variable labels ncombsco 'Combined wealth index' /nurbscor 'Urban wealth index' /nrurscor 'Rural wealth index'.
value labels ncombsco nurbscor nrurscor 1 'Lowest' 2 'Second' 3 'Middle' 4 'Fourth' 5 'Highest'.

*** Check on quintiles.
frequencies variables=ncombsco nurbscor nrurscor.

weight by hhwt.

ctables /table (
  QH101_11+QH101_12+QH101_13+QH101_14+QH101_21+QH101_31+QH101_32+QH101_41+QH101_42+QH101_51+QH101_61+QH101_71+QH101_81+QH101_91+QH101_96+
  QH109_11+QH109_12+QH109_13+QH109_14+QH109_21+QH109_22+QH109_23+QH109_31+QH109_41+QH109_51+QH109_61+QH109_96+
  QH109_11_sh+QH109_12_sh+QH109_13_sh+QH109_14_sh+QH109_21_sh+QH109_22_sh+QH109_23_sh+QH109_31_sh+QH109_41_sh+QH109_51_sh+QH109_96_sh+
  QH112A_1+QH112A_2+QH112A_3+QH112A_4+QH112A_5+QH112A_6+QH112A_7+QH112A_96+
  QH113_1+QH113_2+QH113_3+QH113_4+QH113_5+QH113_95+QH113_96+
  QH121A+QH121B+QH121C+QH121D+QH121F+QH121G+QH121H+QH122A+QH122B+QH122C+QH122D+QH122E+QH122F+
  QH123+QH142_11+QH142_21+QH142_22+QH142_31+QH142_32+QH142_33+QH142_34+QH142_35+QH142_36+QH142_96+
  QH143_11+QH143_12+QH143_22+QH143_23+QH143_31+QH143_32+QH143_35+QH143_96+
  QH144_11+QH144_12+QH144_21+QH144_24+QH144_25+QH144_26+QH144_31+QH144_32+QH144_33+QH144_34+QH144_36+QH144_37+QH144_38+
  QH144_96+HOUSE+LAND+memsleep+
  QH118A_1+QH118A_2+QH118A_3+QH118B_1+QH118B_2+QH118B_3+
  QH118C_1+QH118C_2+QH118C_3+QH118D_1+QH118D_2+QH118D_3+
  QH118E_1+QH118E_2+QH118E_3+QH118F_1+QH118F_2+QH118F_3+
  QH118G_1+QH118G_2+QH118G_3+QH118H_1+QH118H_2+QH118H_3+
  QH118I_1+QH118I_2+QH118I_3+landarea
  )[S][Mean F8.3] by (ncombsco+nurbscor+nrurscor)[C]
  /slabels visible=no.

* Alternative instead of ctables.
*means tables=
  QH101_11 QH101_12 QH101_13 QH101_14 QH101_21 QH101_31 QH101_32 QH101_41 QH101_42 QH101_51 QH101_61 QH101_71 QH101_81 QH101_91 QH101_96
  QH109_11 QH109_12 QH109_13 QH109_14 QH109_21 QH109_22 QH109_23 QH109_31 QH109_41 QH109_51 QH109_61 QH109_96
  QH109_11_sh QH109_12_sh QH109_13_sh QH109_14_sh QH109_21_sh QH109_22_sh QH109_23_sh QH109_31_sh QH109_41_sh QH109_51_sh QH109_96_sh
  QH112A_1 QH112A_2 QH112A_3 QH112A_4 QH112A_5 QH112A_6 QH112A_7 QH112A_96
  QH113_1 QH113_2 QH113_3 QH113_4 QH113_5 QH113_95 QH113_96
  QH120A QH120BA_1 QH120BA_2 QH120BA_3 QH120BB_1 QH120BB_2 QH120BB_3 QH120BC_1 QH120BC_2 QH120BC_3 QH120BD_1 QH120BD_2 QH120BD_3 QH120BE_1 QH120BE_2 QH120BE_3
  QH120BF_1 QH120BF_2 QH120BF_3 QH120BG_1 QH120BG_2 QH120BG_3 QH120BH_1 QH120BH_2 QH120BH_3 QH120BI_1 QH120BI_2 QH120BI_3 QH120BJ_1 QH120BJ_2 QH120BJ_3 QH120BK_1
  QH120BK_2 QH120BK_3 QH120BL_1 QH120BL_2 QH120BL_3 QH120BM_1 QH120BM_2 QH120BM_3 QH120BN_1 QH120BN_2 QH120BN_3 QH120BO_1 QH120BO_2 QH120BO_3 QH120BP_1 QH120BP_2
  QH120BP_3 QH120BQ_1 QH120BQ_2 QH120BQ_3 QH120CA_0 QH120CA_1 QH120CA_99995 QH120CA_99998 QH120CB_0 QH120CB_1 QH120CB_99995 QH120CB_99998 QH120CC_0 QH120CC_1
  QH120CC_99995 QH120CC_99998 QH120CD_0 QH120CD_1 QH120CD_99995 QH120CD_99998 QH120CE_0 QH120CE_1 QH120CE_99995 QH120CE_99998 QH120CF_0 QH120CF_1 QH120CF_99995
  QH120CF_99998 QH120CG_0 QH120CG_1 QH120CG_99995 QH120CG_99998 QH120CH_0 QH120CH_1 QH120CH_99995 QH120CH_99998 QH120CI_0 QH120CI_1 QH120CI_99995 QH120CI_99998
  QH120CJ_0 QH120CJ_1 QH120CJ_99995 QH120CJ_99998 QH120CK_0 QH120CK_1 QH120CK_99995 QH120CK_99998 QH120CL_0 QH120CL_1 QH120CL_99995 QH120CL_99998 QH120CM_0
  QH120CM_1 QH120CM_99995 QH120CM_99998 QH120CN_0 QH120CN_1 QH120CN_99995 QH120CN_99998 QH120CO_0 QH120CO_1 QH120CO_99995 QH120CO_99998 QH120CP_0 QH120CP_1
  QH120CP_99995 QH120CP_99998 QH120CQ_0 QH120CQ_1 QH120CQ_99995 QH120CQ_99998 QH120D QH120EA QH120EB QH120EC QH120ED QH120EE QH120EF QH120EG QH120EH QH120EI
  QH120FA_0 QH120FA_1 QH120FA_99995 QH120FA_99998 QH120FB_0 QH120FB_1 QH120FB_99995 QH120FB_99998 QH120FC_0 QH120FC_1 QH120FC_99995 QH120FC_99998 QH120FD_0
  QH120FD_1 QH120FD_99995 QH120FD_99998 QH120FE_0 QH120FE_1 QH120FE_99995 QH120FE_99998 QH120FF_0 QH120FF_1 QH120FF_99995 QH120FF_99998 QH120FG_0 QH120FG_1
  QH120FG_99995 QH120FG_99998 QH120FH_0 QH120FH_1 QH120FH_99995 QH120FH_99998 QH120FI_0 QH120FI_1 QH120FI_99995 QH120FI_99998 QH120G_1 QH120G_2 QH120G_3
  QH120G_8 QH120H_0 QH120H_1 QH120H_99995 QH120H_99998 QH121A QH121B QH121C QH121D QH121F QH121G QH121H QH122A QH122B QH122C QH122D QH122E QH122F
  QH123 QH142_11 QH142_21 QH142_22 QH142_31 QH142_32 QH142_33 QH142_34 QH142_35 QH142_36 QH142_96
  QH143_11 QH143_12 QH143_21 QH143_22 QH143_23 QH143_31 QH143_32 QH143_35 QH143_36 QH143_96
  QH144_11 QH144_12 QH144_21 QH144_23 QH144_24 QH144_25 QH144_26 QH144_31 QH144_32 QH144_33 QH144_34 QH144_36 QH144_37 QH144_38
  QH144_96 HOUSE LAND memsleep
  QH118A_1 QH118A_2 QH118A_3 QH118B_1 QH118B_2 QH118B_3
  QH118C_1 QH118C_2 QH118C_3 QH118D_1 QH118D_2 QH118D_3
  QH118E_1 QH118E_2 QH118E_3 QH118F_1 QH118F_2 QH118F_3
  QH118G_1 QH118G_2 QH118G_3 QH118H_1 QH118H_2 QH118H_3
  QH118I_1 QH118I_2 QH118I_3 landarea
    by ncombsco nurbscor nrurscor
  /cells mean count stddev.

graph /histogram(normal)=combscor /title= 'Distribution of Households by Wealth Scores'.
frequencies variables=combscor
  /format=notable
  /ntiles=5
  /statistics=stddev minimum maximum semean mean median mode skewness seskew kurtosis sekurt
  /order=analysis.

weight off.
filter off.
write formats combscor urbscore rurscore (f11.5).

* Save final dataset of assets.
save outfile='assets.sav'.

*** Write out scores file.
write outfile='scores.dat' table /QHCLUST QHNUMBER combscor ncombsco urbscore nurbscor rurscore nrurscor.
execute.

* Produce table 2.6 weighted by de jure population to test.
weight by hhmemwt.
compute total = 0.
variable labels total 'Total'.
value labels total 0 ' '.
ctables /vlabels variables=QHTYPE QHPROVINCE total Ncombsco display=both
  /table QHTYPE [C] + QHPROVINCE [C] + total [C] BY Ncombsco [C][rowpct.count '%' F8.1, totals [rowpct.count '%' F8.1, count '' F8.0]]
  /categories variables=Ncombsco total=yes
  /titles title='Table 2.6 Wealth Quintiles' ''
    'Percent distribution of the de jure population by wealth quintiles, according to residence and province, Papua New Guinea DHS 2016-18'
  corner='Residence/province' /slabels visible=no.